Samsung ARM 클록 소스 레지스터 변환 AWK 스크립트

기존 clksrc_clk 필드를 reg_div·reg_src 구조체로 변환하는 절차

이 AWK 스크립트는 Samsung ARM 플랫폼의 기존 `clksrc_clk` C 초기화 블록을 새 레지스터 서술 형식으로 변환하는 일회성 보조 도구입니다. 첫 번째 명령행 인수로 클록 레지스터 헤더를 읽고, 표준 입력으로 들어오는 C 소스에서 각 `clksrc_clk ... = {` 블록을 찾아 `.reg_div`와 `.reg_src` 중첩 초기화 항목을 생성합니다.

사용 예는 `./clksrc-change-registers.awk arch/arm/plat-s5pc1xx/include/plat/regs-clock.h < src > dst`입니다. 헤더 파일은 `_MASK` 매크로의 비트 폭과 shift를 계산하는 참조 자료이고, `src`는 변환할 원본 C 코드, `dst`는 생성 결과입니다. `USB_SIG_MASK`는 헤더 마스크 수집 대상에서 명시적으로 제외됩니다.

스크립트는 원본 식별자와 표현식을 문자열로 다룹니다. `extract_value()`는 초기화 행의 `=` 뒤부터 `,` 앞까지 값을 추출하고, `splitdefine()`은 `#define` 이름과 괄호 안 표현식을 분리합니다. `find_length()`는 `0x1`, `0x3`, `0x7`, `0xf` 마스크만 각각 1·2·3·4비트로 인식하며 다른 값이면 오류를 출력하고 종료합니다.

아래 코드는 Linux v6.18.37 원문 1-166줄 전체입니다. 탭은 표시 안정성을 위해 여덟 칸으로 정규화했지만 AWK 함수명, 변수, 정규식, `getline`, 연관 배열 인덱스, C 필드명, 문자열과 줄 순서는 변경하지 않았습니다.

#!/usr/bin/awk -f
#
# Copyright 2010 Ben Dooks <ben-linux@fluff.org>
#
# Released under GPLv2

# example usage
# ./clksrc-change-registers.awk arch/arm/plat-s5pc1xx/include/plat/regs-clock.h < src > dst

function extract_value(s)
{
    eqat = index(s, "=")
    comat = index(s, ",")
    return substr(s, eqat+2, (comat-eqat)-2)
}

function remove_brackets(b)
{
    return substr(b, 2, length(b)-2)
}

function splitdefine(l, p)
{
    r = split(l, tp)

    p[0] = tp[2]
    p[1] = remove_brackets(tp[3])
}

function find_length(f)
{
    if (0)
        printf "find_length " f "\n" > "/dev/stderr"

    if (f ~ /0x1/)
        return 1
    else if (f ~ /0x3/)
        return 2
    else if (f ~ /0x7/)
        return 3
    else if (f ~ /0xf/)
        return 4

    printf "unknown length " f "\n" > "/dev/stderr"
    exit
}

function find_shift(s)
{
    id = index(s, "<")
    if (id <= 0) {
        printf "cannot find shift " s "\n" > "/dev/stderr"
        exit
    }

    return substr(s, id+2)
}


BEGIN {
    if (ARGC < 2) {
        print "too few arguments" > "/dev/stderr"
        exit
    }

# read the header file and find the mask values that we will need
# to replace and create an associative array of values

    while (getline line < ARGV[1] > 0) {
        if (line ~ /\#define.*_MASK/ &&
            !(line ~ /USB_SIG_MASK/)) {
            splitdefine(line, fields)
            name = fields[0]
            if (0)
                printf "MASK " line "\n" > "/dev/stderr"
            dmask[name,0] = find_length(fields[1])
            dmask[name,1] = find_shift(fields[1])
            if (0)
                printf "=> '" name "' LENGTH=" dmask[name,0] " SHIFT=" dmask[name,1] "\n" > "/dev/stderr"
        } else {
        }
    }

    delete ARGV[1]
}

/clksrc_clk.*=.*{/ {
    shift=""
    mask=""
    divshift=""
    reg_div=""
    reg_src=""
    indent=1

    print $0

    for(; indent >= 1;) {
        if ((getline line) <= 0) {
            printf "unexpected end of file" > "/dev/stderr"
            exit 1;
        }

        if (line ~ /\.shift/) {
            shift = extract_value(line)
        } else if (line ~ /\.mask/) {
            mask = extract_value(line)
        } else if (line ~ /\.reg_divider/) {
            reg_div = extract_value(line)
        } else if (line ~ /\.reg_source/) {
            reg_src = extract_value(line)
        } else if (line ~ /\.divider_shift/) {
            divshift = extract_value(line)
        } else if (line ~ /{/) {
                indent++
                print line
            } else if (line ~ /}/) {
            indent--

            if (indent == 0) {
                if (0) {
                    printf "shift '" shift   "' ='" dmask[shift,0] "'\n" > "/dev/stderr"
                    printf "mask  '" mask    "'\n" > "/dev/stderr"
                    printf "dshft '" divshift "'\n" > "/dev/stderr"
                    printf "rdiv  '" reg_div "'\n" > "/dev/stderr"
                    printf "rsrc  '" reg_src "'\n" > "/dev/stderr"
                }

                generated = mask
                sub(reg_src, reg_div, generated)

                if (0) {
                    printf "/* rsrc " reg_src " */\n"
                    printf "/* rdiv " reg_div " */\n"
                    printf "/* shift " shift " */\n"
                    printf "/* mask " mask " */\n"
                    printf "/* generated " generated " */\n"
                }

                if (reg_div != "") {
                    printf "\t.reg_div = { "
                    printf ".reg = " reg_div ", "
                    printf ".shift = " dmask[generated,1] ", "
                    printf ".size = " dmask[generated,0] ", "
                    printf "},\n"
                }

                printf "\t.reg_src = { "
                printf ".reg = " reg_src ", "
                printf ".shift = " dmask[mask,1] ", "
                printf ".size = " dmask[mask,0] ", "

                printf "},\n"

            }

            print line
        } else {
            print line
        }

        if (0)
            printf indent ":" line "\n" > "/dev/stderr"
    }
}

// && ! /clksrc_clk.*=.*{/ { print $0 }